From 804204db7cf1e8a28defd359d17fa72949e13eff Mon Sep 17 00:00:00 2001
From: Nathan Reiner <nathan@nathanreiner.xyz>
Date: Mon, 31 Aug 2026 23:05:16 +0200
Subject: Implement with ptrCast to make it more transparent.

---
 src/Watcher.zig | 62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 src/Watcher.zig

(limited to 'src/Watcher.zig')

diff --git a/src/Watcher.zig b/src/Watcher.zig
new file mode 100644
index 0000000..4a0a7c3
--- /dev/null
+++ b/src/Watcher.zig
@@ -0,0 +1,62 @@
+const std = @import("std");
+const c = @import("c");
+const zpy = @import("root.zig");
+
+const Self = @This();
+
+id: c_int,
+
+pub const Event = enum(u32) {
+    added = c.PyDict_EVENT_ADDED,
+    modified = c.PyDict_EVENT_MODIFIED,
+    deleted = c.PyDict_EVENT_DELETED,
+    cloned = c.PyDict_EVENT_CLONED,
+    cleared = c.PyDict_EVENT_CLEARED,
+    deallocated = c.PyDict_EVENT_DEALLOCATED,
+};
+
+pub const Callback = fn (Event, *zpy.Dict, *zpy.Object, *zpy.Object) error{Exception}!void;
+
+pub fn add(callback: Callback) !Self {
+    const wrapper = struct {
+        pub fn wrapper(
+            event: c_uint,
+            dict: [*c]c.PyObject,
+            key: [*c]c.PyObject,
+            value: [*c]c.PyObject,
+        ) callconv(.c) c_int {
+            return if (std.meta.isError(callback(
+                @enumFromInt(event),
+                @ptrCast(dict),
+                @ptrCast(key),
+                @ptrCast(value),
+            ))) -1 else 0;
+        }
+    }.wrapper;
+
+    const result = c.PyDict_AddWatcher(&wrapper);
+
+    if (result == -1) {
+        return error.Exception;
+    }
+
+    return .{ .id = result };
+}
+
+pub fn clear(self: Self) !void {
+    if (c.PyDict_Clear(self.id) == -1) {
+        return error.Exception;
+    }
+}
+
+pub fn watch(self: Self, dict: *zpy.Dict) !void {
+    if (c.PyDict_Watch(self.id, @ptrCast(dict)) == -1) {
+        return error.Exception;
+    }
+}
+
+pub fn unwatch(self: Self, dict: *zpy.Dict) !void {
+    if (c.PyDict_Unwatch(self.id, @ptrCast(dict)) == -1) {
+        return error.Exception;
+    }
+}
-- 
cgit v1.2.3-70-g09d2