aboutsummaryrefslogtreecommitdiff
path: root/src/zilch/Component.zig
diff options
context:
space:
mode:
authorNathan Reiner <nathan@nathanreiner.xyz>2026-10-12 09:43:19 +0200
committerNathan Reiner <nathan@nathanreiner.xyz>2026-10-12 09:43:19 +0200
commit0b2af471b6d5dfc4eaf53639102c1b854bbb324b (patch)
treeaba3943b8c54d26d8552d0685d4178bc995d91c3 /src/zilch/Component.zig
parent812f547d84b5ce1a2924ae16f6257e4fd19efcc0 (diff)
first version of zilch
Diffstat (limited to 'src/zilch/Component.zig')
-rw-r--r--src/zilch/Component.zig196
1 files changed, 196 insertions, 0 deletions
diff --git a/src/zilch/Component.zig b/src/zilch/Component.zig
new file mode 100644
index 0000000..35fafbe
--- /dev/null
+++ b/src/zilch/Component.zig
@@ -0,0 +1,196 @@
+const std = @import("std");
+const Fragment = @import("root.zig").html.Fragment;
+const Element = @import("root.zig").html.Element;
+const Attribute = @import("root.zig").html.Attribute;
+const Object = @import("Object.zig");
+
+const Self = @This();
+
+namespace: []const u8 = "app",
+name: []const u8,
+html: Fragment,
+css: []const u8,
+link: type,
+
+fn handlerNeedsEvent(func: anytype) bool {
+ const T = @TypeOf(func);
+ return @typeInfo(T).@"fn".params.len == 2;
+}
+
+fn wrapHandler(ret: anytype) void {
+ const T = @TypeOf(ret);
+ const ret_info = @typeInfo(T);
+
+ if (ret_info == .error_union) {
+ ret catch |err| {
+ std.log.err("error: {}", .{err});
+ };
+ }
+}
+
+fn exportFromHtml(self: *const Self, element: Element) void {
+ comptime {
+ switch (element) {
+ .tag => |tag| for (tag.attributes) |attr| {
+ if (attr.value.len > 0 and attr.value[0] == '@') {
+ const event_handler = @field(self.link, attr.value[1..]);
+
+ const func =
+ if (handlerNeedsEvent(event_handler))
+ struct {
+ pub fn func(obj: *self.link, event: *Object) callconv(.c) void {
+ wrapHandler(event_handler(obj, event));
+ }
+ }.func
+ else
+ struct {
+ pub fn func(obj: *self.link) callconv(.c) void {
+ wrapHandler(event_handler(obj));
+ }
+ }.func;
+
+ @export(
+ &func,
+ .{
+ .name = std.fmt.comptimePrint(
+ "export::{s}::{s}",
+ .{ self.name, attr.value[1..] },
+ ),
+ },
+ );
+ }
+
+ switch (tag.content) {
+ .children => |children| for (children) |child| {
+ self.exportFromHtml(child);
+ },
+ else => {},
+ }
+ },
+ else => {},
+ }
+ }
+}
+
+pub fn exportLinks(self: *const Self) void {
+ const init = struct {
+ pub fn init(element: *Object) callconv(.c) ?*self.link {
+ const obj = std.heap.wasm_allocator.create(self.link) catch return null;
+ if (@hasDecl(self.link, "init")) {
+ wrapHandler(obj.init(element));
+ }
+ return obj;
+ }
+ }.init;
+
+ @export(
+ &init,
+ .{
+ .name = std.fmt.comptimePrint(
+ "export::{s}::init",
+ .{self.name},
+ ),
+ },
+ );
+
+ const deinit = struct {
+ pub fn deinit(obj: *self.link) callconv(.c) void {
+ if (@hasDecl(self.link, "deinit")) {
+ wrapHandler(obj.deinit());
+ }
+ std.heap.wasm_allocator.destroy(obj);
+ }
+ }.deinit;
+
+ @export(
+ &deinit,
+ .{
+ .name = std.fmt.comptimePrint(
+ "export::{s}::deinit",
+ .{self.name},
+ ),
+ },
+ );
+
+ for (self.html.elements) |element| {
+ comptime self.exportFromHtml(element);
+ }
+}
+
+fn linkAttributes(self: *const Self, attributes: []const Attribute) []const Attribute {
+ var linked: []const Attribute = &.{};
+
+ for (attributes) |attr| {
+ if (attr.value.len > 0 and attr.value[0] == '@') {
+ const event_handler = @field(self.link, attr.value[1..]);
+ const attribute: Attribute = .{
+ .name = attr.name,
+ .value = std.fmt.comptimePrint(
+ "wasm_handle_event(this, \"export::{s}::{s}\", event, {})",
+ .{ self.name, attr.value[1..], handlerNeedsEvent(event_handler) },
+ ),
+ };
+ linked = linked ++ .{attribute};
+ } else {
+ linked = linked ++ .{attr};
+ }
+ }
+ return linked;
+}
+
+fn linkHtmlRecursive(self: *const Self, element: Element) Element {
+ comptime {
+ return switch (element) {
+ .tag => |el| .{
+ .tag = .{
+ .name = el.name,
+ .attributes = self.linkAttributes(el.attributes),
+ .content = switch (el.content) {
+ .children => |children| ch: {
+ var elements: []const Element = &.{};
+
+ for (children) |child| {
+ const e: []const Element = &.{self.linkHtmlRecursive(child)};
+ elements = elements ++ e;
+ }
+
+ break :ch .{ .children = elements };
+ },
+ .void => .void,
+ },
+ },
+ },
+ .string => element,
+ };
+ }
+}
+
+pub fn toElement(self: *const Self) []const Element {
+ return &.{
+ .node(
+ "template",
+ .{ .id = "@" ++ self.name },
+ [_]Element{
+ .node("style", .{}, &.{.text(self.css)}),
+ } ++ (html: {
+ var elements: []const Element = &.{};
+
+ for (self.html.elements) |element| {
+ elements = elements ++ .{self.linkHtmlRecursive(element)};
+ }
+
+ break :html elements;
+ }),
+ ),
+ .node(
+ "script",
+ .{},
+ &.{.text(
+ std.fmt.comptimePrint(
+ @embedFile("component.template.js"),
+ .{ self.namespace, self.name, self.name, self.name, self.name },
+ ),
+ )},
+ ),
+ };
+}