1 files changed, 52 insertions, 0 deletions
diff --git a/src/http/serve.zig b/src/http/serve.zig
new file mode 100644
index 0000000..587f4a3
--- /dev/null
+++ b/src/http/serve.zig
@@ -0,0 +1,52 @@
+const std = @import("std");
+
+const RouteSet = @import("RouteSet.zig");
+
+pub fn serve(
+    gpa: std.mem.Allocator,
+    comptime routes: RouteSet,
+    address: std.Io.net.IpAddress,
+) !void {
+    var threaded: std.Io.Threaded = .init(gpa, .{});
+    var group: std.Io.Group = .init;
+    const io = threaded.io();
+    var server = try address.listen(io, .{ .reuse_address = true });
+
+    while (true) {
+        const stream = try server.accept(io);
+        group.async(io, handle, .{ io, gpa, stream, &routes });
+    }
+}
+
+pub fn handle(
+    io: std.Io,
+    gpa: std.mem.Allocator,
+    stream: std.Io.net.Stream,
+    routes: *const RouteSet,
+) void {
+    var read_buffer: [1024 * 8]u8 = undefined;
+    var write_buffer: [1024 * 8]u8 = undefined;
+
+    defer stream.close(io);
+
+    var arena: std.heap.ArenaAllocator = .init(gpa);
+    defer arena.deinit();
+
+    var reader = stream.reader(io, &read_buffer);
+    var writer = stream.writer(io, &write_buffer);
+
+    var server: std.http.Server = .init(&reader.interface, &writer.interface);
+    var request = server.receiveHead() catch |e| {
+        std.debug.print("error: {}\n", .{e});
+        return;
+    };
+
+    std.debug.print("{s} {s}\n", .{ @tagName(request.head.method), request.head.target });
+
+    if (routes.getInterface(request.head.target)) |interface| {
+        const message = interface.handle(gpa, arena.allocator(), io, &request);
+        message.send(io, &request) catch return;
+    } else {
+        request.respond("", .{ .status = .not_found }) catch return;
+    }
+}