aboutsummaryrefslogtreecommitdiff
path: root/src/zeroscript/Component.zig
diff options
context:
space:
mode:
Diffstat (limited to 'src/zeroscript/Component.zig')
-rw-r--r--src/zeroscript/Component.zig190
1 files changed, 190 insertions, 0 deletions
diff --git a/src/zeroscript/Component.zig b/src/zeroscript/Component.zig
new file mode 100644
index 0000000..2f92b70
--- /dev/null
+++ b/src/zeroscript/Component.zig
@@ -0,0 +1,190 @@
+const std = @import("std");
+const Fragment = @import("root.zig").html.Fragment;
+const Element = @import("root.zig").html.Element;
+const Attribute = @import("root.zig").html.Attribute;
+const Object = @import("Object.zig");
+
+const Self = @This();
+
+namespace: []const u8 = "app",
+name: []const u8,
+html: Fragment,
+css: []const u8,
+link: type,
+
+fn handlerNeedsEvent(func: anytype) bool {
+ const T = @TypeOf(func);
+ return @typeInfo(T).@"fn".params.len == 2;
+}
+
+fn wrapHandler(ret: anytype) void {
+ const T = @TypeOf(ret);
+ const ret_info = @typeInfo(T);
+
+ if (ret_info == .error_union) {
+ ret catch |err| {
+ std.log.err("error: {}", .{err});
+ };
+ }
+}
+
+fn exportFromHtml(self: *const Self, element: Element) void {
+ comptime {
+ switch (element) {
+ .tag => |tag| for (tag.attributes) |attr| {
+ if (attr.value.len > 0 and attr.value[0] == '@') {
+ const event_handler = @field(self.link, attr.value[1..]);
+
+ const func =
+ if (handlerNeedsEvent(event_handler))
+ struct {
+ pub fn func(obj: *self.link, event: *Object) callconv(.c) void {
+ wrapHandler(event_handler(obj, event));
+ }
+ }.func
+ else
+ struct {
+ pub fn func(obj: *self.link) callconv(.c) void {
+ wrapHandler(event_handler(obj));
+ }
+ }.func;
+
+ @export(
+ &func,
+ .{
+ .name = std.fmt.comptimePrint(
+ "export::{s}::{s}",
+ .{ self.name, attr.value[1..] },
+ ),
+ },
+ );
+ }
+
+ switch (tag.content) {
+ .children => |children| for (children) |child| {
+ self.exportFromHtml(child);
+ },
+ else => {},
+ }
+ },
+ else => {},
+ }
+ }
+}
+
+pub fn exportLinks(self: *const Self) void {
+ const init = struct {
+ pub fn init(element: *Object) callconv(.c) ?*self.link {
+ const obj = std.heap.wasm_allocator.create(self.link) catch return null;
+ wrapHandler(obj.init(element));
+ return obj;
+ }
+ }.init;
+
+ @export(
+ &init,
+ .{
+ .name = std.fmt.comptimePrint(
+ "export::{s}::init",
+ .{self.name},
+ ),
+ },
+ );
+
+ for (self.html.elements) |element| {
+ comptime self.exportFromHtml(element);
+ }
+}
+
+fn linkAttributes(self: *const Self, attributes: []const Attribute) []const Attribute {
+ var linked: []const Attribute = &.{};
+
+ for (attributes) |attr| {
+ if (attr.value.len > 0 and attr.value[0] == '@') {
+ const event_handler = @field(self.link, attr.value[1..]);
+ const attribute: Attribute = .{
+ .name = attr.name,
+ .value = std.fmt.comptimePrint(
+ "wasm_handle_event(this, \"export::{s}::{s}\", event, {})",
+ .{ self.name, attr.value[1..], handlerNeedsEvent(event_handler) },
+ ),
+ };
+ linked = linked ++ .{attribute};
+ } else {
+ linked = linked ++ .{attr};
+ }
+ }
+ return linked;
+}
+
+fn linkHtmlRecursive(self: *const Self, element: Element) Element {
+ comptime {
+ return switch (element) {
+ .tag => |el| .{
+ .tag = .{
+ .name = el.name,
+ .attributes = self.linkAttributes(el.attributes),
+ .content = switch (el.content) {
+ .children => |children| ch: {
+ var elements: []const Element = &.{};
+
+ for (children) |child| {
+ const e: []const Element = &.{self.linkHtmlRecursive(child)};
+ elements = elements ++ e;
+ }
+
+ break :ch .{ .children = elements };
+ },
+ .void => .void,
+ },
+ },
+ },
+ .string => element,
+ };
+ }
+}
+
+pub fn toElement(self: *const Self) []const Element {
+ return &.{
+ .node(
+ "template",
+ .{ .id = "@" ++ self.name },
+ [_]Element{
+ .node("style", .{}, &.{.text(self.css)}),
+ } ++ (html: {
+ var elements: []const Element = &.{};
+
+ for (self.html.elements) |element| {
+ elements = elements ++ .{self.linkHtmlRecursive(element)};
+ }
+
+ break :html elements;
+ }),
+ ),
+ .node(
+ "script",
+ .{},
+ &.{.text(
+ std.fmt.comptimePrint(
+ \\customElements.define("{s}-{s}", class extends HTMLElement {{
+ \\ constructor() {{
+ \\ super();
+ \\ this.attachShadow({{ mode: 'open' }});
+ \\ const template = document.getElementById("@{s}");
+ \\ const node = document.importNode(template.content, true);
+ \\ this.shadowRoot.appendChild(node);
+ \\ this[ZsPtr] = null;
+ \\ }}
+ \\ connectedCallback() {{
+ \\ wasm_ready.then(() => {{
+ \\ const id = ObjectStore.generateFreeId();
+ \\ ObjectStore.registerObject(id, this);
+ \\ this[ZsPtr] = wasm.exports['export::{s}::init'](id)
+ \\ }});
+ \\ }}
+ \\}})
+ , .{ self.namespace, self.name, self.name, self.name }),
+ )},
+ ),
+ };
+}