aboutsummaryrefslogtreecommitdiff
path: root/src/z/Env/root.zig
blob: 5a08362397d0da0e0c99eab04859913abe3cdb0f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
const std = @import("std");

const js = @import("js.zig");

const Self = @This();

pub const Call = @import("call.zig").Call;
const future = @import("future.zig");
pub const AnyFuture = future.AnyFuture;
pub const Future = future.Future;
pub const Value = @import("value.zig").Value;
pub const Object = @import("Object.zig");

calls: std.ArrayList(Call) = .empty,
values: std.ArrayList(Value) = .empty,
pool: std.heap.MemoryPool(Value) = .empty,
results: std.ArrayList(*Value) = .empty,
gpa: std.mem.Allocator,

pub fn init(gpa: std.mem.Allocator) Self {
    return .{ .gpa = gpa };
}

pub fn getProp(self: *Self, object: *Object, key: anytype) AnyFuture {
    self.calls.append(self.gpa, .{
        .kind = .get_prop,
        .num_args = 2,
    }) catch |err| return .{ .err = err };
    self.values.append(self.gpa, .from(object)) catch |err| return .{ .err = err };
    self.values.append(self.gpa, .from(key)) catch |err| return .{ .err = err };

    return self.registerFuture() catch |err| .{ .err = err };
}

pub fn setProp(
    self: *Self,
    object: *Object,
    key: anytype,
    value: anytype,
) Future(.undefined) {
    self.calls.append(self.gpa, .{
        .kind = .set_prop,
        .num_args = 3,
    }) catch |err| return .fromAny(.{ .err = err });

    self.values.append(self.gpa, .from(object)) catch |err| return .fromAny(.{ .err = err });
    self.values.append(self.gpa, .from(key)) catch |err| return .fromAny(.{ .err = err });
    self.values.append(self.gpa, .from(value)) catch |err| return .fromAny(.{ .err = err });

    return .fromAny(self.registerFuture() catch |err| .{ .err = err });
}

pub fn deleteProp(
    self: *Self,
    object: *Object,
    key: anytype,
) Future(.undefined) {
    self.calls.append(self.gpa, .{
        .kind = .del_prop,
        .num_args = 2,
    }) catch |err| return .fromAny(.{ .err = err });

    self.values.append(self.gpa, .from(object)) catch |err| return .fromAny(.{ .err = err });
    self.values.append(self.gpa, .from(key)) catch |err| return .fromAny(.{ .err = err });

    return .fromAny(self.registerFuture() catch |err| .{ .err = err });
}

pub fn callMethod(
    self: *Self,
    object: *Object,
    key: []const u8,
    args: anytype,
) AnyFuture {
    self.calls.append(self.gpa, .{
        .kind = .call_method,
        .num_args = 2 + args.len,
    }) catch |err| return .{ .err = err };

    self.values.append(self.gpa, .from(object)) catch |err| return .{ .err = err };
    self.values.append(self.gpa, .from(key)) catch |err| return .{ .err = err };

    inline for (args) |arg| {
        self.values.append(self.gpa, .from(arg)) catch |err| return .{ .err = err };
    }

    return self.registerFuture() catch |err| return .{ .err = err };
}

pub fn call(self: *Self, object: *Object, args: anytype) AnyFuture {
    self.calls.append(self.gpa, .{
        .kind = .call,
        .num_args = 1 + args.len,
    }) catch |err| return .{ .err = err };

    self.values.append(self.gpa, .from(object)) catch |err| return .{ .err = err };

    inline for (args) |arg| {
        self.values.append(self.gpa, .from(arg)) catch |err| return .{ .err = err };
    }

    return self.registerFuture() catch |err| return .{ .err = err };
}

pub fn free(self: *Self, object: *Object) Future(.undefined) {
    self.calls.append(self.gpa, .{
        .kind = .free,
        .num_args = 1,
    }) catch |err| return .fromAny(.{ .err = err });

    self.values.append(self.gpa, .from(object)) catch |err| return .fromAny(.{ .err = err });

    return .fromAny(self.registerFuture() catch |err| .{ .err = err });
}

pub fn new(self: *Self, object: *Object, args: anytype) Future(.object) {
    self.calls.append(self.gpa, .{
        .kind = .new,
        .num_args = 1 + args.len,
    }) catch |err| return .fromAny(.{ .err = err });

    self.values.append(self.gpa, .from(object)) catch |err| return .fromAny(.{ .err = err });

    inline for (args) |arg| {
        self.values.append(self.gpa, .from(arg)) catch |err| return .fromAny(.{ .err = err });
    }

    return .fromAny(self.registerFuture() catch |err| .{ .err = err });
}

fn registerFuture(self: *Self) !AnyFuture {
    const result = try self.pool.create(self.gpa);
    errdefer self.pool.destroy(result);
    result.kind = .uninit;
    try self.results.append(self.gpa, result);
    return .{ .result = result };
}

pub fn flush(self: *Self) void {
    js.process(
        @ptrCast(self.calls.items),
        @ptrCast(self.values.items),
        @ptrCast(self.results.items),
        self.results.items.len,
    );
    self.calls.clearRetainingCapacity();
    self.values.clearRetainingCapacity();
    self.results.clearRetainingCapacity();
}

pub fn deinit(self: *Self) void {
    self.flush();

    self.calls.deinit(self.gpa);
    self.values.deinit(self.gpa);
    self.pool.deinit(self.gpa);
    self.results.deinit(self.gpa);

    self.* = undefined;
}