aboutsummaryrefslogtreecommitdiff
path: root/src/zilch/Component.zig
blob: 3a813012fa8e6ce20d95b1d6d3a899456de82a63 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
const std = @import("std");
const Fragment = @import("root.zig").html.Fragment;
const Element = @import("root.zig").html.Element;
const Attribute = @import("root.zig").html.Attribute;
const Object = @import("Object.zig");
const Env = @import("root.zig").Env;
const Function = Env.Function;
const Future = Env.Future;

const Self = @This();

pub const Options = struct {
    namespace: []const u8 = "app",
    name: []const u8,
    html: Fragment,
    css: []const u8,
    link: type,
};

namespace: []const u8,
name: []const u8,
html: Fragment,
css: []const u8,
link: type,
id: u32,

pub fn build(comptime options: Options) Self {
    return .{
        .namespace = options.namespace,
        .name = options.name,
        .html = options.html,
        .css = options.css,
        .link = options.link,
        .id = std.hash.XxHash32.hash(4654, options.namespace ++ "-" ++ options.name),
    };
}

fn handlerNeedsEvent(func: anytype) bool {
    const T = @TypeOf(func);
    return @typeInfo(T).@"fn".param_types.len == 2;
}

fn wrapHandler(ret: anytype) void {
    const T = @TypeOf(ret);
    const ret_info = @typeInfo(T);

    if (ret_info == .error_union) {
        ret catch |err| {
            std.log.err("error: {}", .{err});
        };
    }
}

fn exportFromHtml(self: *const Self, element: Element) void {
    comptime {
        switch (element) {
            .tag => |tag| for (tag.attributes) |attr| {
                if (attr.value.len > 0 and attr.value[0] == '@') {
                    const event_handler = @field(self.link, attr.value[1..]);

                    const func =
                        if (handlerNeedsEvent(event_handler))
                            struct {
                                pub fn func(obj: *self.link, event: *Object) callconv(.c) void {
                                    wrapHandler(event_handler(obj, event));
                                }
                            }.func
                        else
                            struct {
                                pub fn func(obj: *self.link) callconv(.c) void {
                                    wrapHandler(event_handler(obj));
                                }
                            }.func;

                    @export(
                        &func,
                        .{
                            .name = std.fmt.comptimePrint(
                                "export::{s}::{s}",
                                .{ self.name, attr.value[1..] },
                            ),
                        },
                    );
                }

                switch (tag.content) {
                    .children => |children| for (children) |child| {
                        self.exportFromHtml(child);
                    },
                    else => {},
                }
            },
            else => {},
        }
    }
}

pub fn exportLinks(self: *const Self) void {
    const init = struct {
        pub fn init(element: *Object) callconv(.c) ?*self.link {
            const obj = std.heap.wasm_allocator.create(self.link) catch return null;
            if (@hasDecl(self.link, "init")) {
                wrapHandler(obj.init(element));
            }
            return obj;
        }
    }.init;

    @export(
        &init,
        .{
            .name = std.fmt.comptimePrint(
                "export::{s}::init",
                .{self.name},
            ),
        },
    );

    for (self.html.elements) |element| {
        comptime self.exportFromHtml(element);
    }
}

fn linkAttributes(self: *const Self, attributes: []const Attribute) []const Attribute {
    var linked: []const Attribute = &.{};

    for (attributes) |attr| {
        if (attr.value.len > 0 and attr.value[0] == '@') {
            const event_handler = @field(self.link, attr.value[1..]);
            const attribute: Attribute = .{
                .name = attr.name,
                .value = std.fmt.comptimePrint(
                    "wasm_handle_event(this, \"export::{s}::{s}\", event, {})",
                    .{ self.name, attr.value[1..], handlerNeedsEvent(event_handler) },
                ),
            };
            linked = linked ++ .{attribute};
        } else {
            linked = linked ++ .{attr};
        }
    }
    return linked;
}

fn linkHtmlRecursive(self: *const Self, element: Element) Element {
    comptime {
        return switch (element) {
            .tag => |el| .{
                .tag = .{
                    .name = el.name,
                    .attributes = self.linkAttributes(el.attributes),
                    .content = switch (el.content) {
                        .children => |children| ch: {
                            var elements: []const Element = &.{};

                            for (children) |child| {
                                const e: []const Element = &.{self.linkHtmlRecursive(child)};
                                elements = elements ++ e;
                            }

                            break :ch .{ .children = elements };
                        },
                        .void => .void,
                    },
                },
            },
            .string => element,
        };
    }
}

pub fn toElement(self: *const Self) []const Element {
    return &.{
        .node(
            "template",
            .{ .id = "@" ++ self.name },
            [_]Element{
                .node("style", .{}, &.{.text(self.css)}),
            } ++ (html: {
                var elements: []const Element = &.{};

                for (self.html.elements) |element| {
                    elements = elements ++ .{self.linkHtmlRecursive(element)};
                }

                break :html elements;
            }),
        ),
        .node(
            "script",
            .{},
            &.{.text(
                std.fmt.comptimePrint(
                    @embedFile("component.template.js"),
                    .{
                        self.namespace,
                        self.name,
                        self.name,
                        self.name,
                    },
                ),
            )},
        ),
    };
}

pub fn new(self: Self, obj: *self.link, env: *Env) Future(*Object) {
    return .fromAny(env.call(bindings.new, .{ @as(usize, @intCast(self.id)), @intFromPtr(obj) }));
}

const bindings = struct {
    pub const new: Function = .from(
        \\function(name_id, ptr) {
        \\  const el = document.createElement(component_registry[name_id]);
        \\  el[ZsPtr] = ptr;
        \\  const id = ObjectStore.generateFreeId();
        \\  ObjectStore.registerObject(id, el);
        \\  return el;
        \\}
    );
};

pub const functions = [_]Function{
    bindings.new,
};