aboutsummaryrefslogtreecommitdiff
path: root/src/zilch/app/root.document.zig
blob: 8e2ca6165a0b3437edca18431af360ce67ab0a09 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
const std = @import("std");

const mod = @import("../root.zig");
const Element = mod.html.Element;
const Document = mod.html.Document;

const Options = @import("Options.zig");

pub fn App(comptime options: Options) type {
    const components: []const Element, const registry: []const u8 = (comp: {
        var cs: []const Element = &.{};
        var registry: []const u8 = "const component_registry = {";

        for (options.components) |component| {
            cs = cs ++ component.toElement();
            registry = registry ++ std.fmt.comptimePrint("{}: '{s}-{s}',", .{
                component.id,
                component.namespace,
                component.name,
            });
        }

        registry = registry ++ "};";

        break :comp .{ cs, registry };
    });

    const functions: []const u8 = func: {
        var buf: []const u8 = "ObjectStore.methods = {";

        for (options.functions) |function| {
            buf = buf ++ std.fmt.comptimePrint("{}: {s},", .{ function.id, function.content });
        }

        buf = buf ++ "}";

        break :func buf;
    };

    return struct {
        const node: Document = .{
            .root = .node("html", .{}, &.{
                .node("head", .{}, &.{
                    .node("title", .{}, &.{.text(options.name)}),
                    .void("link", .{ .rel = "icon", .href = options.favicon }),
                    .void("meta", .{
                        .name = "viewport",
                        .content = "width=device-width, initial-scale=1.0, maximum-scale=1.0, user-scalable=0",
                    }),
                    .void("meta", .{ .charset = "utf8" }),
                    .node("style", .{}, &.{.text(options.theme)}),
                    .node("script", .{}, &.{.text(@embedFile("symbols.js"))}),
                    .node("script", .{}, &.{.text(@embedFile("object-store.js"))}),
                    .node("script", .{}, &.{.text(functions)}),
                    .node("script", .{}, &.{.text(@embedFile("event.js"))}),
                    .node("script", .{}, &.{.text(@embedFile("load.js"))}),
                    .node("script", .{}, &.{.text(reg: {
                        var register_code: []const u8 = "";

                        for (options.globals, 1..) |field, id| {
                            register_code = register_code ++ std.fmt.comptimePrint(
                                "ObjectStore.registerObject({}, {s});",
                                .{ id, field.name },
                            );
                        }

                        break :reg register_code;
                    })}),
                }),
                .node(
                    "body",
                    .{},
                    &[_]Element{
                        .node("script", .{}, &.{.text(registry)}),
                    } ++ components ++ options.body.elements,
                ),
            }),
        };

        html: []const u8 = str: {
            @setEvalBranchQuota(100_000);
            break :str std.fmt.comptimePrint("{f}", .{node});
        },

        pub const init: @This() = .{};
    };
}